libunwind/test/CMakeLists.txt

include(AddLLVM) # for add_lit_testsuite
include(HandleLitArguments)
macro(pythonize_bool var)
  if (${var})
    set(${var} True)
  else()
    set(${var} False)
  endif()
endmacro()

# Install targets required to run libunwind tests into a temporary location.
#
# This ensures that we run the tests against the final installed products, which
# is closer to what we actually ship than the contents of the build tree.
set(LIBUNWIND_TESTING_INSTALL_PREFIX "${LIBUNWIND_BINARY_DIR}/test-suite-install")
set(libunwind_test_suite_install_targets unwind-headers unwind)
if ("libcxx" IN_LIST LLVM_ENABLE_RUNTIMES)
  list(APPEND libunwind_test_suite_install_targets cxx-headers cxx cxx-modules cxxabi-headers cxxabi)
endif()
foreach(target IN LISTS libunwind_test_suite_install_targets)
  add_custom_target(libunwind-test-suite-install-${target} DEPENDS "${target}"
                    COMMAND "${CMAKE_COMMAND}" --install "${CMAKE_BINARY_DIR}"
                                               --prefix "${LIBUNWIND_TESTING_INSTALL_PREFIX}"
                                               --component "${target}")
  add_dependencies(unwind-test-depends libunwind-test-suite-install-${target})
endforeach()

pythonize_bool(HAVE_GETAUXVAL)
pythonize_bool(HAVE_ELF_AUX_INFO)
pythonize_bool(LIBUNWIND_ENABLE_ASSERTIONS)
pythonize_bool(LIBUNWIND_ENABLE_CET)
pythonize_bool(LIBUNWIND_ENABLE_GCS)
pythonize_bool(LIBUNWIND_ENABLE_THREADS)
pythonize_bool(LIBUNWIND_USES_ARM_EHABI)

file(WRITE "${CMAKE_BINARY_DIR}/check_cfi_set_ra_state.s" "
    .text
    .global _test_cfi_set_ra_state
_test_cfi_set_ra_state:
    .cfi_startproc
    .cfi_set_ra_state 0, 0
    ret
    .cfi_endproc
")
set(_previous_CMAKE_TRY_COMPILE_TARGET_TYPE ${CMAKE_TRY_COMPILE_TARGET_TYPE})
set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)
try_compile(HAVE_CFI_SET_RA_STATE
    "${CMAKE_BINARY_DIR}/check_cfi_set_ra_state"
    SOURCES "${CMAKE_BINARY_DIR}/check_cfi_set_ra_state.s"
)
set(CMAKE_TRY_COMPILE_TARGET_TYPE ${_previous_CMAKE_TRY_COMPILE_TARGET_TYPE})
pythonize_bool(HAVE_CFI_SET_RA_STATE)

set(AUTO_GEN_COMMENT "## Autogenerated by libunwind configuration.\n# Do not edit!")
set(SERIALIZED_LIT_PARAMS "# Lit parameters serialized here for llvm-lit to pick them up\n")

serialize_lit_string_param(SERIALIZED_LIT_PARAMS compiler "${CMAKE_CXX_COMPILER}")
serialize_lit_string_param(SERIALIZED_LIT_PARAMS cmake "${CMAKE_COMMAND}")
serialize_lit_string_param(SERIALIZED_LIT_PARAMS cmake_generator "${CMAKE_GENERATOR}")
serialize_lit_string_param(SERIALIZED_LIT_PARAMS cmake_make_program "${CMAKE_MAKE_PROGRAM}")

if (LIBUNWIND_EXECUTOR)
  message(DEPRECATION "LIBUNWIND_EXECUTOR is deprecated, please add executor=... to LIBUNWIND_TEST_PARAMS")
  serialize_lit_string_param(SERIALIZED_LIT_PARAMS executor "${LIBUNWIND_EXECUTOR}")
endif()

serialize_lit_param(SERIALIZED_LIT_PARAMS enable_experimental False)

if (LLVM_USE_SANITIZER)
  serialize_lit_string_param(SERIALIZED_LIT_PARAMS use_sanitizer "${LLVM_USE_SANITIZER}")
endif()

if (CMAKE_CXX_COMPILER_TARGET)
  serialize_lit_string_param(SERIALIZED_LIT_PARAMS target_triple "${CMAKE_CXX_COMPILER_TARGET}")
else()
  serialize_lit_string_param(SERIALIZED_LIT_PARAMS target_triple "${LLVM_DEFAULT_TARGET_TRIPLE}")
endif()

serialize_lit_params_list(SERIALIZED_LIT_PARAMS LIBUNWIND_TEST_PARAMS)

configure_file("${CMAKE_CURRENT_SOURCE_DIR}/configs/cmake-bridge.cfg.in"
               "${CMAKE_CURRENT_BINARY_DIR}/cmake-bridge.cfg"
               @ONLY)

configure_lit_site_cfg(
  "${LIBUNWIND_TEST_CONFIG}"
  ${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg
  MAIN_CONFIG "${CMAKE_CURRENT_SOURCE_DIR}/lit.cfg.py")

add_lit_testsuite(check-unwind "Running libunwind tests"
  ${CMAKE_CURRENT_BINARY_DIR}
  DEPENDS unwind-test-depends)