/*
 * Copyright (c) 2014 Advanced Micro Devices, Inc.
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */

#include "math32.h"
#include "remainderF_piby2.h"
#include "sincosF_piby4.h"

__attribute__ ((overloadable, always_inline)) float
sincos(float x, float *result_cos)
{
    int ix = as_int(x);
    int ax = ix & 0x7fffffff;
    float dx = as_float(ax);

    // Almost all args should be caught in the first branch
    float r0, r1;
    int regn = argReductionS(&r0, &r1, dx);

    float ss = sinf_piby4_new(r0, r1);
    float cc = cosf_piby4_new(r0, r1);

    int flip = (regn > 1) << 31;
    float s = (regn & 1) != 0 ? cc : ss;
    s = as_float(as_int(s) ^ flip ^ (ax ^ ix));
    ss = -ss;
    float c = (regn & 1) != 0 ? ss : cc;
    c = as_float(as_int(c) ^ flip);

    c = ax >= PINFBITPATT_SP32 ? as_float(QNANBITPATT_SP32) : c;
    s = ax >= PINFBITPATT_SP32 ? as_float(QNANBITPATT_SP32) : s;

    *result_cos = c;
    return s;
}

#if __OPENCL_C_VERSION__ < 200
__attribute__ ((overloadable, always_inline)) float
sincos(float x, __local float *result_cos)
{
    float c;
    float s = sincos(x, &c);
    *result_cos = c;
    return s;
}

__attribute__ ((overloadable, always_inline)) float
sincos(float x, __global float *result_cos)
{
    float c;
    float s = sincos(x, &c);
    *result_cos = c;
    return s;
}
#endif